home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 090 / v7n13.arc / QFN.ASM < prev    next >
Encoding:
Assembly Source File  |  1988-06-06  |  8.9 KB  |  251 lines
  1.         name    qfn
  2.         title   QFN.ASM --- qualify file name
  3.         page    55,132
  4. ;
  5. ;
  6. ; QFN.ASM -- Qualify File Name
  7. ;
  8. ; Copyright (C) 1988 Ziff Davis
  9. ; by Ray Duncan Feb. 1988
  10. ;
  11. ; Call with:    DS:SI = filename address
  12. ;               AX    = length
  13. ;
  14. ; Returns:      Carry = clear if filename OK
  15. ;               DS:SI = qualified filename
  16. ;               AX    = length
  17. ;               or
  18. ;               Carry = set if bad filename
  19. ; 
  20. ;               Registers other than DS:SI
  21. ;               and AX are preserved.
  22. ;
  23.  
  24. DGROUP  group   _DATA
  25.  
  26. _DATA   segment word public 'DATA'
  27.  
  28. cdrive  db      0               ; current drive
  29. cpath   db      '\',64 dup (0)  ; current directory
  30.  
  31. tbuff   db      64 dup (0)      ; target directory
  32.  
  33. qbuff   db      'X:\'           ; qualified pathname
  34.         db      64 dup (0)
  35.  
  36. fname   dw      ?               ; filename address
  37. flen    dw      ?               ; filename length
  38.  
  39. _DATA   ends
  40.  
  41.  
  42. _TEXT   segment word public 'CODE'
  43.  
  44.         assume  cs:_TEXT,ds:DGROUP
  45.  
  46.         public  qfn             ; make visible to Linker
  47.  
  48. qfn     proc    near            ; qualify file name
  49.  
  50.         push    bx              ; save registers        
  51.         push    cx
  52.         push    dx
  53.         push    di
  54.         push    es
  55.  
  56.         mov     flen,ax         ; save length and 
  57.         mov     fname,si        ; address of filename
  58.  
  59.         mov     ax,ds           ; make DGROUP addressable
  60.         mov     es,ax           ; with ES register
  61.  
  62.                                 ; save current drive...
  63.         mov     ah,19h          ; fxn 19h = get drive
  64.         int     21h             ; transfer to MS-DOS
  65.         mov     cdrive,al       ; save it
  66.  
  67.                                 ; save current directory...
  68.                                 ; DS:SI = buffer
  69.         mov     si,offset DGROUP:cpath+1
  70.         mov     ah,47h          ; fxn 47h = get directory
  71.         mov     dl,0            ; drive = current
  72.         int     21h             ; transfer to MS-DOS
  73.  
  74.                                 ; did caller specify drive?
  75.         mov     di,fname        ; get address of name
  76.         mov     cx,flen         ; get length of name
  77.  
  78.         cmp     cx,2            ; if drive, length must 
  79.                                 ; be >= 2 chars.
  80.         jl      qfn2            ; too short, no drive
  81.  
  82.                                 ; check for drive delimiter
  83.         cmp     byte ptr [di+1],':'
  84.         jne     qfn2            ; no delimiter, jump
  85.  
  86.         mov     dl,[di]         ; get ASCII drive code
  87.         or      dl,20h          ; fold to lower case
  88.         sub     dl,'a'          ; convert it to binary
  89.         mov     ah,0eh          ; fxn 0eh = select drive
  90.         int     21h             ; transfer to MS-DOS
  91.  
  92.                                 ; get current drive to
  93.                                 ; make sure drive selected
  94.         mov     ah,19h          ; fxn 19h = get current drive
  95.         int     21h             ; transfer to MS-DOS
  96.         cmp     dl,al           ; current = requested?
  97.         je      qfn1            ; jump if select succeeded
  98.         jmp     qfn8            ; exit, select failed
  99.  
  100. qfn1:   add     di,2            ; bump pointer past drive
  101.         sub     cx,2            ; and decrement length
  102.  
  103. qfn2:                           ; save current directory
  104.                                 ; again for new drive...
  105.                                 ; DS:SI = buffer
  106.         mov     si,offset DGROUP:cpath+1
  107.         mov     ah,47h          ; fxn 47h = get directory
  108.         mov     dl,0            ; drive = current
  109.         int     21h             ; transfer to MS-DOS
  110.  
  111.                                 ; scan off path if any
  112.         push    di              ; save start of path
  113.         mov     al,'\'          ; path delimiter
  114.  
  115. qfn3:   mov     fname,di        ; save path pointer
  116.         mov     flen,cx         ; save path length
  117.         jcxz    qfn4            ; jump if none left
  118.  
  119.         repne scasb             ; any '\' left in path?
  120.         je      qfn3            ; loop if '\' found
  121.  
  122. qfn4:   pop     si              ; recover starting address
  123.                                 ; of path portion
  124.  
  125.                                 ; copy path to local buffer
  126.                                 ; and make it ASCIIZ...
  127.         mov     di,offset DGROUP:tbuff
  128.         mov     cx,fname        ; calculate path length
  129.         sub     cx,si
  130.         jz      qfn6            ; jump, no path at all
  131.         cmp     cx,1            ; root directory?
  132.         je      qfn5            ; jump if root
  133.         dec     cx              ; else discard last '\'
  134.  
  135. qfn5:   rep movsb               ; transfer path and
  136.         xor     al,al           ; append null byte
  137.         stosb
  138.         
  139.                                 ; now make target directory
  140.                                 ; the current directory...
  141.         mov     dx,offset DGROUP:tbuff
  142.         mov     ah,3bh          ; fxn 3BH = select directory
  143.         int     21h             ; transfer to MS-DOS
  144.         jc      qfn8            ; jump, no such directory
  145.  
  146. qfn6:                           ; build up full pathname...
  147.  
  148.         mov     ah,19h          ; get current drive
  149.         int     21h             ; transfer to MS-DOS
  150.         add     al,'A'          ; convert binary to ASCII
  151.         mov     qbuff,al        ; store ASCII drive code
  152.  
  153.                                 ; get current directory
  154.         mov     dl,0            ; DL = 0 for default drive
  155.                                 ; DS:SI = buffer address
  156.         mov     si,offset DGROUP:qbuff+3
  157.         mov     ah,47h          ; fxn 47h = get current dir
  158.         int     21h             ; transfer to MS-DOS
  159.         jc      qfn8            ; jump if error 
  160.  
  161.                                 ; point to path component
  162.         mov     di,offset DGROUP:qbuff+3
  163.         cmp     byte ptr [di],0 ; is current directory
  164.                                 ; the root directory?
  165.         je      qfn7            ; yes, jump
  166.  
  167.         xor     al,al           ; scan for null byte at
  168.         mov     cx,-1           ; end of path name
  169.         repne scasb             ; and append backslash
  170.         mov     byte ptr [di-1],'\'
  171.  
  172. qfn7:                           ; now append filename
  173.                                 ; to drive and path...
  174.         mov     si,fname        ; filename address
  175.         cmp     byte ptr [si],'.'
  176.         je      qfn8            ; exit if directory alias
  177.         mov     cx,flen         ; filename length
  178.         rep movsb               ; copy it
  179.                                         
  180.                                 ; set DS:SI = address 
  181.         mov     si,offset DGROUP:qbuff
  182.         mov     ax,di           ; and AX = length of
  183.         sub     ax,si           ; fully qualified filename
  184.  
  185.         call    makelc          ; fold filename to lower
  186.                                 ; case to make it pretty
  187.  
  188.         clc                     ; Carry = false to 
  189.                                 ; indicate success
  190.  
  191.         jmp     qfn9            ; jump to common exit
  192.  
  193. qfn8:                           ; come here if any 
  194.                                 ; error detected...
  195.  
  196.         stc                     ; Carry = true to 
  197.                                 ; indicate error
  198.  
  199. qfn9:   pushf                   ; save Carry flag
  200.         push    ax              ; save final length
  201.  
  202.                                 ; restore original directory
  203.         mov     dx,offset DGROUP:cpath
  204.         mov     ah,3bh          ; fxn 3BH = select directory
  205.         int     21h             ; transfer to MS-DOS
  206.  
  207.         mov     dl,cdrive       ; restore original drive
  208.         mov     ah,0eh          ; fxn 0EH = set drive
  209.         int     21h             ; transfer to MS-DOS
  210.  
  211.         pop     ax              ; restore length
  212.         popf                    ; and Carry flag
  213.  
  214.         pop     es              ; restore other affected
  215.         pop     di              ; registers
  216.         pop     dx
  217.         pop     cx
  218.         pop     bx
  219.  
  220.         ret                     ; back to caller
  221.  
  222. qfn     endp
  223.  
  224.  
  225. makelc  proc    near            ; string -> lower case
  226.                                 ; DS:SI = address
  227.                                 ; AX = length
  228.  
  229.         push    bx              ; save BX contents
  230.         xor     bx,bx           ; BX will be pointer
  231.  
  232. mlc1:                           ; change A-Z to a-z
  233.         cmp     byte ptr [bx+si],'A'
  234.         jb      mlc2
  235.         cmp     byte ptr [bx+si],'Z'
  236.         ja      mlc2
  237.         or      byte ptr [bx+si],20h
  238.  
  239. mlc2:   inc     bx              ; advance through string
  240.         cmp     bx,ax           ; done with string yet?
  241.         jne     mlc1            ; no, check next char.
  242.  
  243.         pop     bx              ; restore BX and
  244.         ret                     ; return to caller
  245.  
  246. makelc  endp
  247.  
  248. _TEXT   ends
  249.  
  250.         end
  251.